Interactive Media Design Review 1999/Interactive Media Design Review 1999.iso/pc/Demos/Bombardier_PC/BSCRIPTS.CST/00111_Script_generalRollandJump

Text File | 1999-04-25 | 5KB | 184 lines

-- ⌐ 1998 @radical.media, inc. & Concurrent New Media Group, L.L.C.
-- Developed for Bombardier, Inc.
--
-- All programming developed by:
-- Robert Fabricant, Valerie Valoueva, Ossi Shaked,
-- Henry Sauvageot, Chris Howell & Chris Girand
--
-- Use of this code by parties other than @radical.media, inc. or their
--agents
-- without the express written consent of @radical.media, inc. AND Concurrent
-- New Media Group, L.L.C. is strictly prohibited.
------------------------------------------------------
--This is a script of a button that takes to a curtain frame defined by #frameName property when cicked. Each button consists of two elements: #bmp "Picture" and #richText "Field". Both elements are linked and should be percieved by user as a whole: one element's rollover triggers the other element's rollover.

property mySprite, NeutralName, HiliteName, pictSprite,PictNeuName,PictHilName,frameName, myRect,rolledOver


on getPropertyDescriptionList
  set description = [:]
  addProp description, #frameName,[#format:#string,¼
                                       #default:"",#comment:"enter the frame name  you wanna go to"]
  return description
end


on new me
  global soundPlayed -- rollover sound trigger

  set mySprite = the spriteNum of me

  set NeutralName = getNeutralName(me, mySprite)

  if neutralName contains "field" then
    set PictNeuName = getPictNeuName (me)
    set pictSprite = getSpriteNumFromMemberName (PictNeuName)
    set PictHilName = PictNeuName&"-hil"

    --Rollover sound effect shouldn't play again
    --if mouse leaves "field" and rolles over "Picture"
    --and vice versa. Boundaries between "field" and "Picture"
    --sould be seamless. The following code calculates an
    --imaginary rectangle around the button to set the sound
    --trigger off if mouse is within that rectangle.
    set textWidth = the width of member neutralName
    set textHeight = the height of member neutralName
    set butWidth = the width of member PictNeuName
    set butHeight = the height of member PictNeuName
    if the left of sprite mySprite > the left of sprite pictSprite then
      set startH = the left of sprite pictSprite - butWidth/2
      set startV = the top of sprite pictSprite - butHeight/2
    else
      set startH = the left of sprite mySprite
      set startV = the top of sprite mySprite
    end if
    set startPoint = point(startH,startV)
    set endH = startH + butWidth + textWidth
    set endV = startV + max(butHeight,textHeight)
    set endPoint = point(endH,endV)
    set myRect = rect(startPoint,endPoint)

    set soundPlayed = FALSE
    set rolledOver = FALSE --one screen may hane more then one
                           --of this buttons. By setting and checking
                           --this property, we make sure that the sound
                           --trigger is set off for the same button it was set on

  else
    set HiliteName = NeutralName&"-hil"
  end if




end


on exitFrame me
  global soundPlayed
  if neutralName contains "field" then
    set mouseLoc = point(the mouseH, the mouseV)
    if inside (mouseLoc,myRect) then
      set rolledOver = TRUE
      if not soundPlayed then
        puppetsound 3, "subRollOld"
        set soundPlayed = TRUE
      end if
    else
      if rolledOver then
        set soundPlayed = FALSE
        set rolledOver = FALSE
      end if

    end if
  end if



end


on mouseWithin me
  if neutralName contains "field" then
    set the member of sprite pictSprite = member  PictHilName
  else
    set the member of sprite mySprite = member  hiliteName
  end if
  updatestage
end

on mouseLeave me
  if neutralName contains "field" then
    set the member of sprite pictSprite = member  PictNeuName
  else
    set the member of sprite mySprite = member  NeutralName
  end if

end

on mouseUp me
  global  cockpitRetFrame
  puppetsound 1, "mouse5"

  cursor -1
  if not(NeutralName contains "print") then
    if frameName = "" then
      go to frame cockpitRetFrame
    else
      go to frame frameName
    end if
  end if

  set gContollerList = []

end






on getNeutralName me,SpriteNum

  set aMember = the member of sprite spriteNum
  set Name = the name of member aMember
  if Name contains "-" then
    repeat with i = the Number of Chars of Name down to 1
      if char i of Name <> "-" then
        delete char i of Name
      else
        delete char i of Name
        exit repeat
      end if
    end repeat
  end if


  return Name

end


on getPictNeuName me
  set Name = neutralName

  repeat with i = the Number of Chars of Name down to 1
    if char i of Name <> "_" then
      delete char i of Name
    else
      delete char i of Name
      exit repeat
    end if
  end repeat



  return Name
end